Hi Guys!! Im having a trouble in SalesLogix Campaigns.. When i try to add a group like a campaign target, gives me the error: "Multiple-step  operation generated errors. Check each status value .."

<p>  
Sub AddTargetsToGrid(strSQL, Grid, Label, strGroup, strType, blnDisplayMsg)
    Dim objRS, objGridRS
    Dim i

    cmdAddTargets.Enabled = False
    Set objRS = objSLXDB.GetNewRecordset
    objRS.Open strSQL, objSLXDB.Connection
    objRS.ActiveConnection = Nothing
    If DisplayAddTargetsMsg(objRS.RecordCount, blnDisplayMsg) Then
       Set objGridRS = Grid.Recordset

       For i = 0 To objRS.RecordCount - 1
           With objGridRS
                If .RecordCount > 0 Then
                   .MoveFirst
                End If
                .Find("ENTITYID='" & objRS.Fields(0).Value & "'") 'DNL

                'If the record wasn't found add it
                If .EOF Then
                   .AddNew
                   .Fields(1).Value = objRS.Fields(0).Value    'EntityID (key field constraint)
                   .Fields(2).Value = strType                  'Target Type            ###################> ERROR IN THIS LINE
                   .Fields(3).Value = strGroup                 'Group Name
                   .Fields(4).Value = objRS.Fields(1).Value    'Account
                   .Fields(5).Value = objRS.Fields(2).Value    'First Name
                   .Fields(6).Value = objRS.Fields(3).Value    'Last Name
                   .Fields(7).Value = objRS.Fields(4).Value    'Email
                   If not strType = "Lead" then
                   '  .Fields(8).Value = objRS.Fields(5).Value    'City
                   '  .Fields(9).Value = objRS.Fields(6).Value    'State
                   '  .Fields(10).Value = objRS.Fields(7).Value   'Zip
                   End If
                   .Fields(11).Value = objRS.Fields(8).Value   'Work Phone

                   If gBlnEditMode And Not gBlnShowPreview Then
                      AddToManageTargetsRS objRS.Fields(0).Value, strType, strGroup
                   End If
                End If
           End With
           objRS.MoveNext
       Next
       Grid.Recordset = objGridRS
    End If
    objRS.Close
    Set objRS = Nothing
    cmdAddTargets.Enabled = True
    EnableDisableButtons
    SelectFirstRecordForGrid(grdTargets)
End Sub


Function CreateTargetsRSStructure
    Dim objRS

    Set objRS = objSLXDB.GetNewRecordSet
    With objRS
        .Fields.Append "CAMPAIGNTARGETID", adVarChar, 12 'DNL
        .Fields.Append "ENTITYID", adVarChar, 12, adFldFixed 'DNL
        .Fields.Append "TARGETTYPE", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "GROUPNAME", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "ACCOUNT", adVarChar, 128, adFldIsNullable 'DNL
        .Fields.Append "FIRSTNAME", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "LASTNAME", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "EMAIL", adVarChar, 128, adFldIsNullable 'DNL
        .Fields.Append "CITY", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "STATE", adVarChar, 32, adFldIsNullable 'DNL
        .Fields.Append "POSTALCODE", adVarChar, 24, adFldIsNullable 'DNL
        .Fields.Append "WORKPHONE", adVarChar, 32, adFldIsNullable 'DNL
        .Open
    End With
    Set CreateTargetsRSStructure = objRS
End Function

Sub DefineTargetsGrid(objGrid)
    Dim col

    'CampaignTargetID column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "CAMPAIGNTARGETID" 'DNL
    col.Visible = False
    'EntityID column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "ENTITYID" 'DNL
    col.Visible = False
    'Target Type column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "TARGETTYPE" 'DNL
    col.Visible = False
    'Group Name column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "GROUPNAME" 'DNL
    col.Visible = False
    'First Name column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "FIRSTNAME" 'DNL
    col.Caption = Application.Translator.Localize("Nome")
    col.Width = 65
    'Last Name column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "LASTNAME" 'DNL
    col.Caption = Application.Translator.Localize("Sobrenome")
    col.Width = 75
    'Account column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "ACCOUNT" 'DNL
    col.Caption = Application.Translator.Localize("Company")
    col.Width = 160
    col.Sorted = 2
    'Email column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "EMAIL" 'DNL
    col.Caption = Application.Translator.Localize("Email")
    col.Width = 147
    'City State Zip column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "CITY" 'DNL
    col.Caption = Application.Translator.Localize("City")
    col.Width = 85
    col.Visible = False
    'State column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "STATE" 'DNL
    col.Caption = Application.Translator.Localize("State")
    col.Width = 45
    col.Visible = False
    'Zip column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "POSTALCODE" 'DNL
    col.Caption = Application.Translator.Localize("Zip")
    col.Width = 60
    col.Visible = False
    'Work Phone column
    Set col = objGrid.Columns.Add(0)
    col.FieldName = "WORKPHONE" 'DNL
    col.Caption = Application.Translator.Localize("Work Phone")
    col.Width = 95
    col.FormatType = ftPhone
    col.Visible = False
End Sub

 

Someone can help me?

Thanks!!

Rafael S.

HI Rafeal,

That error usually means the data is bigger than what the field will take or it is the wrong fromat like a string in a date field.

Since the value that you are referencing is Type my guess would be it is null and the field is not nullable or somone coded it to a value too large.

Your best bet is to run SLX Profiler and capture the SQL being passed during the error and then you should see the problem.

Best, Brian

What's the value and datta type of strType just prior to this statement?

   .Fields(2).Value = strType                  'Target Type            ###################> ERROR IN THIS LINE

Hi Brian!! Thanks for the answer!!! I will lookup for this..thanks so much!!

And RJ Samp, the value of strType is "Contact"...thats because i feel strange...because the value is not too long, and in the creation of the structure of recordset, the size is bigger than this string ("contact").... thanks for answer my post!!