Dim mm
Dim doc
Dim t

    On Error Resume Next
    Set mm = CreateObject("MindManager.Application")

    If Err.Number = 429 Then
        MsgBox "MindManager is not installed.", 48, "Error"
        Exit Sub
    End If
    On Error Goto 0

    mm.Visible = True    
    Set doc = mm.Documents.Item(0)

    With doc.CentralTopic
        'create the main topic text
        .Text = "Tester Main Topic"
        
        'add sub-topics
        .AddSubTopic "Tester 1"
        .AddSubTopic "Tester 2"
        Set t = .AddSubTopic("Tester 3")
        
        'add sub-topics under the "Tester 3" sub-topic
        t.AddSubTopic "Sub Topic 1 of 4"
        t.AddSubTopic "Sub Topic 2 of 4"
        t.AddSubTopic "Sub Topic 3 of 4"
        Set t = t.AddSubTopic("Sub Topic 4 of 4")
        
        'add properties to the "Sub Topic 4 of 4" sub-topic
        t.Icons.AddStockIcon 32 'mmStockIconResource1
        t.CreateHyperlink "mailto:me@mail.com"
        t.Notes.Text = "This is a test to see some notes"
    End With
    
    Set t = Nothing
    Set doc = Nothing
    Set mm = Nothing

• Displaying account hierarchies. A parent account would be represented by the central topic which would branch out to child-accounts.
• Displaying account overview & action items. The account as the central topic branching out to items such as:
  • Tickets branching also to associated activities for each ticket.
  • Contacts branching out to activities for each contact.
  • Opportunities branching out to any activities for the opportunity.
• Importing tasks from a MindManager map to SalesLogix.
• Exporting any custom data, such as projects, campaigns, events, etc to MindManager.

Option Explicit

Class AccountMindManager

Private m_accountid

Public Property Let AccountID(ByVal val)
    m_accountid = val
End Property

Public Property Get AccountID()
    AccountID = m_accountid
End Property

Public Function IsMindManagerInstalled()
Dim mm

    On Error Resume Next

    Set mm = CreateObject("MindManager.Application")
    IsMindManagerInstalled = (Err.Number <> 429)

    Set mm = Nothing
    On Error Goto 0
End Function

Public Sub CreateDocument()
Dim mm
Dim doc
Dim t
Dim rs
Dim id

    If Not IsMindManagerInstalled Then
        MsgBox "MindManager is not installed on your computer.", 48, "MindManager Not Installed"
        Exit Sub
    End If
    If Trim(m_accountid) = "" Then
        Err.Raise 1000, "AccountID property has not been set."
        Exit Sub
    End If

    Set mm = CreateObject("MindManager.Application")

    mm.Visible = True
    Set doc = mm.Documents.Add(True)

    'add account as central contact
    doc.CentralTopic.Text = GetScalarValue("account", "account", "accountid = '" & m_accountid & "'")

    'add contacts
    Set rs = GetData("contactid, lastname, firstname, email", "contact", "accountid = '" & m_accountid & "'")
    With rs
         While Not (.BOF Or .EOF)
             id = .Fields("contactid").Value

             Set t = doc.CentralTopic.AddSubTopic(.Fields("firstname").Value & " " & .Fields("lastname").Value)
             t.Icons.AddStockIcon 32 'mmStockIconResource1
             If Trim(.Fields("email").Value & "") <> "" Then
                 t.CreateHyperlink "mailto:" & .Fields("email").Value
             End If

             AddContactActivities id, t

             Set t = Nothing
             .MoveNext
         Wend
         .Close
    End With
    Set rs = Nothing

    Set doc = Nothing
    Set mm = Nothing
End Sub

Private Sub AddContactActivities(ByVal ContactID, ByRef ParentTopic)
Dim rs
Dim topic
Dim task
Dim acttype
Dim text

    Set rs = GetData("activityid, type, description, startdate, notes", "activity", "contactid = '" & ContactID & "'")
    With rs
        While Not (.BOF Or .EOF)
            acttype = .Fields("type").Value & ""
            text = GetTypeText(acttype) & " (" & .Fields("startdate").Value & ") " & .Fields("description").Value

            Set topic = ParentTopic.AddSubTopic(text)
            topic.Icons.AddStockIcon GetTypeIcon(acttype)
            topic.Notes.Text = .Fields("notes").Value & ""

            Set task = topic.Task
            task.Categories = GetTypeText(acttype)
            task.DueDate = .Fields("startdate").Value
            task.StartDate = .Fields("startdate").Value

            Set task = Nothing
            Set topic = Nothing
            .MoveNext
        Wend
    End With
End Sub

Private Function GetScalarValue(ByVal Field, ByVal Table, ByVal Where)
Dim rs

    Set rs = Application.GetNewConnection.Execute("select " & Field & " from " & Table & " where " & Where)

    With rs
         If Not (.BOF Or .EOF) Then
             GetScalarValue = .Fields(0).Value & ""
         Else
             GetScalarValue = ""
         End If
         .Close
    End With
    Set rs = Nothing
End Function

Private Function GetData(ByVal Fields, ByVal Table, ByVal Where)
    Set GetData = Application.GetNewConnection.Execute("select " & Fields & " from " & Table & " where " & Where)
End Function

Private Function GetTypeText(ByVal ActivityType)
Dim text

    Select Case Trim(ActivityType)
    Case "262153" text = "Document"
    Case "262154" text = "E-Mail"
    Case "262155" text = "Fax"
    Case "262163" text = "Literature Request"
    Case "262145" text = "Meeting"
    Case "262148" text = "Note"
    Case "262162" text = "Personal Activity"
    Case "262146" text = "Phone Call"
    Case "262160" text = "Process"
    Case "262147" text = "To-Do"
    Case Else text = ""
    End Select

    GetTypeText = text
End Function

Private Function GetTypeIcon(ByVal ActivityType)
Dim ico

    Select Case Trim(ActivityType)
    Case "262154" ico = 10 'mmStockIconEmail
    Case "262155" ico = 42 'mmStockIconFax
    Case "262163" ico = 67 'mmStockIconBook
    Case "262145" ico = 61 'mmStockIconMeeting
    Case "262148" ico = 63 'mmStockIconNote
    Case "262146" ico = 40 'mmStockIconCellphone
    Case "262147" ico = 62 'mmStockIconCheck
    Case Else ico = 67 'mmStockIconBook
    End Select

    GetTypeIcon = ico
End Function

End Class

Dim mm

    Set mm = New AccountMindManager
    mm.AccountID = Form.CurrentID
    mm.CreateDocument