1. Grab the first and last name of the lead in SalesLogix (and optionally the company name as well to further narrow the results)
2. Form a URL for searching the LinkedIn site for the lead
3. Get the HTML for the URL (which will contain the results of the search)
4. Parse the HTML to determine the results of the search (e.g.: number of matches found, no matches found, or the SalesLogix user is not logged into LinkedIn)
5. Update the screen to show the number of results found and provide a click able link. We'll use a single hyperlink-style label for this, displaying the results in the caption of the label and place the URL we'll launch in the hint property of the label.

Dim xmlhttp

Sub CheckLinkedIn
Dim url

    Set xmlhttp = CreateObject("Msxml2.XMLHttp")
    ' use the values from the nedName control holding the lead name
    url = "http://www.linkedin.com/ns?search=&name=" & nedName.NameFirst & "+" & nedName.NameLast
    ' optionally use the company name to further narrow down the search
    If chkUseCompany.Checked Then url = url & "&company=" & Replace(txtCompany.Text, " ", "+")

    ' we'll use a label to show the results and also store the URL (so we can load that if clicked)
    ' store the URL in the hint property
    lnkGotoLinkedIn.Caption = "Retrieving LinkedIn status"
    lnkGotoLinkedIn.Hint = url

    With xmlhttp
        'open request async (passing False as the 3rd param tells it to do this asynchronously)
        .Open "GET", url, False
        'register callback function. Using VBScript's "GetRef" function we can pass a
        'pointer to the function we want invoked when complete 
        .OnReadyStateChange = GetRef("HandleLinkedInCallback")
        'send request
        .Send
    End With
End Sub

' This is the callback function that will be invoked by XMLHTTP when complete
Sub HandleLinkedInCallback
Dim result
Dim count
Dim i

    With xmlhttp
        If .ReadyState = 4 Then

            ' get the HTML from the request so we can parse it
            result = xmlhttp.ResponseText

            If InStr(1, result, "noresults", 1) <> 0 Then
                ' no matched results
                lnkGotoLinkedIn.Caption = "No matches found"
            ElseIf InStr(1, result, "we found", 1) <> 0 Then
                ' results found, parse the number of results out of the HTML
                i = InStr(1, result, "<strong name=""numResults"">", 1) + 26
                count = Mid(result, i, InStr(i, result, "</strong>", 1) - i)
                lnkGotoLinkedIn.Caption = count & " LinkedIn matches found"
            ElseIf InStr(1, result, "login-nonuser", 1) <> 0 Then
                ' not logged into LinkedIn
                menuLinkedIn.Items.Items(1).Enabled = False
                lnkGotoLinkedIn.Caption = "Log-in"
                lnkGotoLinkedIn.Hint = "https://www.linkedin.com/secure/login"
            Else
                ' something else went wrong - maybe LinkedIn has changed the search results page
                menuLinkedIn.Items.Items(1).Enabled = False
                lnkGotoLinkedIn.Caption = "Error processing LinkedIn status"
                lnkGotoLinkedIn.Hint = "http://www.linkedin.com/"
            End If
        End If
    End With
End Sub